MicroConverter в Technical Замечание uC001

MicroConverter в I²C в Compatible Interface

Ver 2.0 October 2000 www.analog.com/microconverter в I²C is a Registered Trademark of Philips Semiconductors Inc в MicroConverter is a Registered Trademark of Analog Devices Inc

Это Техническое описание излагает применение интерфейса I²C, аппаратное (в режиме ведомого) и программное (в режиме ведущего), используя Микроконвертор. Это техническое описание также содержит пример кода, каким образом ведущий и ведомый могут общаться друг с другом, используя I²C совместимый интерфейс.

Основные особенности шины I²C следующие:

· Требуется только две линии; линия данных (SDATA) и линия синхроимпульсов (SCLOCK). Обе эти линии двунаправленные, что означает, как ведущий, так и ведомый выступают и в роли передатчика и в роли приемника.

· Ведущий I² C может связываться со многими ведомыми устройствами. Поскольку каждое ведомое устройство имеет уникальный 7-битовый адрес, следовательно, одно отношение master/slave может существовать все время даже в многоведомом окружении.

· Программное обеспечение ведущего может выводить данные со скоростью примерно 140 kbit/s используя 12MHz частоту синхронизации. Аппаратное обеспечение ведомого, может принимать синхросигнал и данные с частотой выше 3.4Mbit/s.

· Микросхема фильтрует выбросы длительностью< 50ns на линиях SDATA и SCLOCK , чтобы сохранить целостность данных.

Типовая схема включения интерфейса I²C показана на рисунке 1 ниже.

Рисунок 1. Один ведущий и несколько ведомых I²C.

1.1 ОБЗОР ИНТЕРФЕЙСА I²C.

Двух проводная система последовательного интерфейса I²C, разработанная фирмой Philips, предоставляет возможность иметь много ведущих и много ведомых связанных между собой двумя линиями (SCLOCK и SDATA). Интерфейс I²C должен иметь как минимум одного ведущего и одного ведомого.

Линия SCLOCK управляет передачей данных между ведущим и ведомым. Сигнал SCLOCK всегда передается от ведущего к ведомому. (Ведомый, тем не менее, имеет возможность удерживать линию в низком состоянии, если он не готов начать прием следующей передачи. Это называется УДЕРЖАНИЕ СИНХРОИМПУЛЬСА ‘Clock Stretching’ (смотри раздел 1.7)). Для передачи каждого бита должен использоваться один синхроимпульс.

1.2 ПОСЛЕДОВАТЕЛЬНОСТЬ ПЕРЕДАЧИ ДАННЫХ I²C.

Замечание: состояния НАЧАЛО (и ОСТАНОВ) - единственное время, когда линия SDATA должна измениться в течение высокого периода линии SCLOCK. Во время передачи данных (включая обращение ведомых) данные на линии SDATA должны находиться в одном и том же состоянии во время, когда линия SCLOCK находится в состоянии ВЫСОКО.

Если адрес ведомого, соответствует адресу, который посылает ведущий, тогда ведомый автоматически пошлет Подтверждение (ACK), иначе он пошлет Неподтверждение (NACK). ACK показан как НИЗКИЙ УРОВЕНЬ на линии(строке) SDATA на 9-ом тактовом импульсе. NACK показан как ВЫСОКИЙ УРОВЕНЬ на линии SDATA на 9-ом тактовом импульсе (рисунок 3).

В I2C ISR (или в голосованном выполнении or in a polled implementation) ведомый решает, можно ли передать или принять в соответствии с состоянием R/W бита, который посылает ведущий. Ведомый тогда или передает или принимает информационный бит на каждый синхроимпульс, который посылает ведущий. Ведущий обеспечивает выработку 9 синхроимпульсов (8 для данных и 1 для ACK) для того, чтобы ведомый мог передать / получить данные на/из ведущего. I2CI бит будет устанавливаться каждый раз, когда байт достоверных данных передан / получен ведомым.

Этот раздел описывает I 2 C реализацию Микроконвертор. Микроконвертор позволяет осуществлять оба режима: аппаратно для ведомого и программно для ведущего. Для управления I 2 C интерфейсом используются три SFRs:

I2CADD: содержит 7-bit адрес устройства (по умолчанию = 55H).

I2CDAT: В режиме ведомый приемник принимает данные по линии SDATA и пересылает в этот SFR.

I2CCON: Хранит конфигурационные и управляющие биты для режимов ведущего и ведомого как описано в таблице 1.

В Микроконвертор интерфейс I²C в режиме ведущего осуществляется программным путем. Пользователь должен программировать побитно линии SDATA и SCLOCK. Режим ведущего задается установкой бита I2CM в регистре I2CCON.

Бит MDI устанавливается если SDATA в высоком состоянии и сбрасывается если SDATA в низком состоянии (provided MDE is cleared).

• Читать состояние линии SDATA невозможно (MDI bit) если MDE в низком состоянии (если она не соединена с другим портовым разъемом).
• Невозможно прочесть состояние линии SCLOCK (если она не соединена с другим портовым разъемом).
• Поскольку ведущий реализуется программно, то в I2C работа прерываний не используется.

В Микроконвертор ведомый реализован аппаратно. По умолчанию микросхема находится в режиме ведомого. Работа интерфейса I²C (в противоположность интерфейсу SPI) активизируется по сбросу бита SPE регистра SPICON SFR (SPE=0 по умолчанию). Адрес I²C хранится в регистре I2CADD. Принимаемые или передаваемые данные хранятся в регистре I2CDAT.

Режим ведомого устанавливается сбросом бита I2CM регистра I2CCON. По умолчанию состояние ведомого I²C находится в ожидании состояния START. Микроконвертор установит бит I2CI, когда он опознает условие старта с последующим действительным адресом и битом направления R/W (то есть I2CI установит 8 bits после условия start если адрес соответствует).

Порт I²C не генерирует прерывание пока пользователь не сконфигурирует должным образом систему прерываний I²C, установив бит регистра IE2/IEIP2 SFR а также общее прерывание бит EA в регистре IE SFR. i.e.

ADuC812S/ADuC816/ADuC824 : Авто сброс бита I2CI реализован так, что бит автоматически сбрасывается после чтения или записи регистра I2CDAT SFR.

Пользователь может выбирать: опрашивать ли ему бит I2CI, или установить режим прерываний. По прерыванию в счетчик команд заносится адрес вектора 003BH по завершении заполнении байта. Первый принятый байт будет I2CI ISR 7-bit адрес и бит R/W будет находиться в регистре I2CDAT SFR то есть, только что полученный байт.

Бит I2CTX содержит бит R/W посланный ведущим. Если бит I2CTX установлен, ведомый передаст данные записанные в регистр I2CDAT. Если же бит I2CTX сброшен, ведомый будет принимать данные в регистр I2CDAT. Программное обеспечение может опрашивать состояние бита I2CTX для того, чтобы определить, является ли, надо ли записывать в регистр или читать из регистра I2CDAT.

Когда принято условие STOP, интерфейс сбрасывается в состояние, в котором ожидается прием адреса (idle). Также, если принимается NACK в конце последовательности, то также происходит возврат к состоянию по умолчанию (idle state). Бит I2CRS может быть использован для сброса интерфейса I²C. Этот бит может использоваться для возврата интерфейса в состояние по умолчанию.

• Микроконвертор (slave) не отвечает на общий вызов General Call Address (0000 000).

• Микроконвертор не поддерживает повторный START.

· Clock stretching используется для связи быстрого ведущего с медленным ведомым. Когда ведомый принимает свой адрес или достоверные данные линия SCLOCK автоматически удерживается на нижнем уровне. После того как бит I2CI будет сброшен программой, ведомый отпускает линию SCLOCK. Для использования clock stretching ведущий должен иметь возможность читать состояние линии SCLOCK и задерживать выдачу новых данных до тех пор, пока ведомый не освободит линию SCLOCK.

Микроконвертор в режиме ведущего не может читать состояние линии SCLOCK интерфейса I²C. Для чтения состояния линии SCLOCK, линия SCLOCK должна быть соединена с каким то другим цифровым вводом и, читая его, можно будет определить, освободил ли ведомый линию SCLOCK или нет.

Для арбитража необходимо читать содержимое линии SDATA для сравнения с тем, что выдано и что есть на самом деле, на линии SDATA. В Микроконвертор ведущий не может читать состояние линии SDATA и интерфейса I²C. Для чтения состояния линии SDATA, необходимо линию SDATA подключить к другому цифровому входу ведущего.

• Отсутствуют резисторы подтягивающие линии SDATA/SCLOCK к плюсу.

• I2CI должен сбрасываться программно, используя команду CLR I2CI (сброс только один раз)

• I²C бит разрешения прерывания (ESI) и I²C бит приоритета прерываний (PSI) регистра IE2 SFR (SFR адрес A9h) и IP SFR (SFR адрес B8h) соответственно.

· Слабое подтягивание (примерно 20mA) на выходах SDATA/SCLOCK. Это подтягивание включается только когда выбран режим I²C. Для режима SPI эти подтягивающие резисторы отключаются. В системе со многими ведомыми внешнее подтягивание может быть необходимо.

· Бит прерывания I2CI автоматически сбрасывается при чтении или записи регистра I2CDAT SFR выполняемого программой. Повторный сброс этого бита может привести к потере данных соответственно надо быть уверенным, что только раз за прерывание он сбрасывается.

· Прерывание I²C устанавливается битом (ESI) и битом приоритета прерывания I2C (PSI) оба в регистре IEIP2 SFR (SFR адрес A9h) IEIP2.0 и IEIP2.4 соответственно.

Здесь описывается программа ведущего I2C mstr.asm. Эта программа может использоваться совместно с программой I2Cslave.asm на двух микропроцессорах и показывает работу ведущего и ведомого Микроконвертор. Этот код демонстрирует работу (I2Cmstr.asm) интерфейса I²C в режиме ведущего.

Ведущий посылает условие START, адрес ведомого, и бит R/W (устанавливая для начала ведущего приемником) ведомому. Затем он принимает один байт от ведомого, посылает ему NACK и условие STOP. NACK показывает ведомому, что ведущий принял последний байт переданный ведомым. Затем он посылает условие START, адрес ведомого и бит R/W (сброшенный для обозначения передачи) ведомому опять. Затем ведущий передает ведомому байт. После передачи байта он проверяет ACK и посылает условие STOP. Ведущий затем посылает принятый байт через UART на PC, где он может быть просмотрен на мониторе. Программа возвращается на начало и принимает символ от ведомого опять.

SLAVEADD: Slaveadd содержит адрес ведомого, к которому мы обращаемся. В данном случае ведомый имеет адрес 44h, это означает, что ведущий должен посылать 88h (или 89h) как описано в разделе 1.3.

OUTPUT: Output содержит значение передаваемое ведомому, здесь оно 0h.

INPUT: Input значение принятое от ведомого. Это значение посылается на UART.

NOACK: Устанавливается если NACK получен когда ACK ожидался.

ERR: Флаг ERR устанавливается, если NOACK устанавливается где то в программе, и позволяет флагу NOACK быть сброшенным в программе. Если флаг ERR устанавливается в конце программы, сообщение об ошибке посылается на UART.

Configuratio n: конфигурируются UART и Внешнее прерывание External Interrupt 0 (INT0).
UART: UART конфигурируется на скорость 9600.
External Interrupt 0: Устанавливается EX0/IT0 для разрешения прерывания INT0.
Установка EA разрешает прерывания.

Инициализация: Инициализируются регистры I²C и флаги.

I2CCON = A8h => Режим ведущего
Выклюсение выходного драйвера SDATA
SCLOCK в высокий
OUTPUT = 0 Инициализация байта передачи в ‘0’.

Замечание: Поскольку интерфейс I²C в режиме ведущего не требует установки прерывания I²C, или засылки значения в I2CADD.

1) Посылка START BIT
2) Посылка адреса ведомому Slave address (R/W бит установлен на прием)
3) Проверка ACK.
4) Если принят NACK, посылается STOP бит и устанавливается флаг ERR
5) Если принят ACK посылается 8 синхроимпульсов на ведомое устройство, читая бит MDI после каждого переданного синхроимпульса. После 8 синхроимпульса принятый байт записывается в INPUT
6) Посылка NACK показывает, что был принят последний байт
7) Посылка STOP BIT.
8) Если принят NACK устанавливается флаг ERR.

1) Посылается START BIT
2) Посылается адреса ведомому Slave address (R/W бит сброшен для передачи)
3) Проверяется ACK
4) Если принят NACK, посылается STOP бит и устанавливается флаг ERR
5) Если принят ACK тогда посылаются 8 синхроимпульсов ведомому устройству. На каждый бит MDO в I2CCON должен быть загружено соответствующее значение из байта данных OUTPUT.
6) Проверка ACK
8) Если принят NACK, устанавливается флаг ERR.
8) Посылка STOP BIT
Опрос ошибки: Проверка флага ошибки ERR для проверки наличия ошибки. Если имеется ошибка, то посылается сообщение через UART на PC.

Transmit i/p: Передается введенный байт через UART на PC.

Toggle LED: Каждая вспышка LED соответствует приему байта от ведомого и что байт переданный ведущим возвращен ведомым.

Check RI: Если байт принят ведущим из UART, тогда байт грузится в OUTPUT и в дальнейшем будет передавать это значение как новый OUTPUT.

INTO ISR: Нажатие клавиши INT0 на отладочной плате (evaluation board) (causing an INT0 interrupt) вызовет наращивание выдаваемого байта.

$MOD812 ; использует ADuC812 & 8052 предопределенные имена
;$MOD816
;$MOD824

;____________________________________________________________________

BITCNT DATA 30h ; счетчик бит для I2C процедур
SLAVEADD DATA 31h ; адрес ведомого для I2C процедур
INPUT DATA 32h ; данные принятые от ведомого
OUTPUT DATA 33h ; данные передаваемые ведомому
NOACK BIT 00h ; I2C флаг неподтверждения
ERR BIT 00h ; I2C флаг ошибки
LED EQU P3.4

;____________________________________________________________________

CSEG
ORG 0000h
JMP MAIN

;____________________________________________________________________

ORG 0003h

INC OUTPUT

RETI

;____________________________________________________________________

ORG 0060h
MAIN:
; конфигурирование UART ADuC812
MOV SCON,#52h ; конфигурирование скорости UART 9600
MOV TMOD,#20h ; подразумевается частота 11.0592MHz
MOV TH1,#-3
SETB TR1

;============================================================
; ПОДПРОГРАММЫ
;============================================================

; посылка всей последовательности ведомому ; (slave address + data (OUTPUT)) SENDDATA:
; посылка start
CALL STARTBIT ; активация линии и посылка адреса ведомому
; посылка адреса ведомого
MOV A, SLAVEADD
CALL SENDBYTE ; установка NOACK если NACK принят
JB NOACK, STOPSEND ; если нет подтверждения, то посылка stop
; посылка байта OUTPUT
MOV A, OUTPUT
CALL SENDBYTE ; установить NOACK если принят NACK
STOPSEND:
CALL STOPBIT ; посылка stop
JNB NOACK, SENDRET ; если ведомый посылает NACK послать ошибку
SETB ERR ; установить флаг ошибки
SENDRET:
RET

;____________________________________________________________________

; прием одного или более байтов данных от ведомого по I2C.
RCVDATA:
INC SLAVEADD ; Установить RW на прием
; послать start
CALL STARTBIT ; активация линии и посылка адреса ведомому
; послать адрес ведомого
MOV A, SLAVEADD
CALL SENDBYTE ; установить NOACK если принят NACK
DEC SLAVEADD ; вернуть прежний адрес SLAVEADD в 88h (после INC)
JB NOACK, STOPRCV ; Проверить соответствие ведомого.
CALL RCVBYTE ; Принять следующий байт данных.
MOV INPUT,A ; Сохранить байт данных в буфере.
STOPRCV:
CALL STOPBIT
JNB NOACK, RCVRET ; если ведомый послал NACK послать ошибку
SETB ERR ; установить флаг ошибки
RCVRET:
RET

;____________________________________________________________________

; STARTBIT
; Посылка start для инициализации обмена по I2C
STARTBIT:
SETB MDE ; установить линию SDATA на выдачу
CLR NOACK
CLR MDO ; обнуление O/P на SDATA
CLR MCO ; start bit
RET

;____________________________________________________________________

; STOPBIT
; Послать stop для завершения передачи по I2C
STOPBIT:
SETB MDE ; установить линию SDATA на выдачу
CLR MDO ; подготовить SDATA для stop
SETB MCO ; установить синхро для stop
SETB MDO ; Это stop
RET

;____________________________________________________________________

; SENDBYTE
; Send 8-bits in ACC ведомому
SENDBYTE:
MOV BITCNT,#8 ; 8 бит в байте
SETB MDE ; установка линии SDATA на выдачу
CLR MCO ; убеждаемся в том что линия clock в низком состоянии
SENDBIT:
RLC A ; сдвигаем бит данных для выдачи в перенос (carry)
MOV MDO,C ; выдача бита данных на линию SDATA
SETB MCO ; выдаем синхроимпульс
CLR MCO ; сбрасываем синхроимпульс
DJNZ BITCNT,SENDBIT ; возвращаемся назад пока не выданы все 8 бит
CLR MDE ; сбрасываем линию данных для подтверждения
SETB MCO ; посылаем синхроимпульс для подтверждения
JNB MDI,NEXT ; опрос подтверждения
SETB NOACK ; нет подтверждения, устанавливаем флаг
NEXT: CLR MCO ; сбрасываем синхроимпульс
RET

;____________________________________________________________________
; RCVBYTE
; получение байта данных по I2C от ведомого. Результат приема
; возвращается в A
RCVBYTE:
MOV BITCNT,#8 ; Установить число бит.
CLR MDE ; установить разрешение линии SDATA на ввод CLR MCO ; убеждаемся что линия синхроимпульса в низком состоянии
RCVBIT:
SETB MCO ; синхроимпульс на прием бита
CLR MCO ; сброс синхроимпульса
MOV C,MDI ; чтение бита информации в carry.
RLC A ; Сдвиг бита в байт результата.
DJNZ BITCNT,RCVBIT ; Повторение пока принимаются биты.
; принятый байт в аккумуляторе
SETB MDE ; Data pin =Output for NACK
SETB MDO ; Send NACK (всегда посылается NACK для
; последнего переданного байта)
SETB MCO ; Послать NACK синхроимпульс.
CLR MCO
RET

;____________________________________________________________________

; DELAY
; DELAY ROUTINE FOR THE ADuC812/ADuC816/ADuC824
DELAY: ; Задержка на 100ms * A
; ADuC812 100ms based on 11.0592MHz Core Clock
; ADuC824 100ms based on 1.573MHz Core Clock
MOV R2,A ; Acc содержит величину задержки
DLY0: MOV R3,#200 ; Установка delay loop0
DLY1: MOV R4,#229 ; Установка delay loop1
DJNZ R4,$ ; Dec R4 & Jump here until R4 is 0
; wait here for 131*15.3us=2ms
DJNZ R3,DLY1 ; Dec R3 & Jump DLY1 until R3 is 0
; Wait for 50*2ms
DJNZ R2,DLY0 ; Dec R2 & Jump DLY0 until R2 is 0
; wait for ACC*100ms
RET ; возврат из подпрограммы

;____________________________________________________________________

; ERROR
; эта подпрограмма посылает если NACK принято от ведомого
ERROR:
MOV A,#45h
CALL SENDCHAR ; посылка символа E через UART RET

;____________________________________________________________________

; SENDCHAR
; sends ASCII value contained in A to UART
SENDCHAR:
JNB TI,$ ; ожидание передачи символа
CLR TI ; сброс TI
MOV SBUF,A
RET

;____________________________________________________________________

;____________________________________________________________________

; SENDVAL
; преобразование hex значения A в два символа ASCII, и выдача их
; через UART. Значение A не изменяется.
SENDVAL:
PUSH ACC
SWAP A
CALL HEX2ASCII
CALL SENDCHAR ; посылка старшего полубайта
POP ACC
PUSH ACC
CALL HEX2ASCII
CALL SENDCHAR ; посылка младшего полубайта
POP ACC
RET

;____________________________________________________________________

END

;============================================================

;============================================================

;____________________________________________________________________

; ОПРЕДЕЛНИЕ ПЕРЕМЕННЫХ ВО ВНУТРЕННЕЙ ПАМЯТИ
BYTECNT DATA 30h ; счетчик байт для I2C процедур
INPUT DATA 31h ; данные полученные от ведущего
OUTPUT DATA 32h ; данные для передачи ведущему
GO BIT 00h ; флаг ожидания прерывания
FIRST BIT 01h ; флаг индицирующий первое принятое прерывание Int
LED EQU P3.4 ; P3.4 управляет LED на отладочной плате

;____________________________________________________________________

; Начало кода
CSEG
ORG 0000h
JMP MAIN

;____________________________________________________________________

; обработчик прерывания NT0 ISR
ORG 0003h
INC OUTPUT
RETI

;____________________________________________________________________

; I2C ISR обработчик прерывания
ORG 003Bh
JB I2CTX, SLAVE_TRANSMITTER
SLAVE_RECEIVER:
JB FIRST, ENDINT1 ; если первый INT тогда ждем следующего прерывания
SETB GO ; прием завершен
MOV INPUT, I2CDAT ; запись принятых данных в INPUT
JMP ENDINT1
SLAVE_TRANSMITTER:

SETB GO ; передача завершена
MOV I2CDAT, OUTPUT ; занесение данных для передачи в I2CDAT
ENDINT1:
CLR I2CI ; сброс бита I2C прерывания (только для 812)
; JMP ENDINT2 ; Note: для ADuC824/816 чтение или
; запись регистра I2CDAT
; автоматически сбрасывает i2ci. Если
; I2CI сбросить дважды это
; вызовет ошибку MicroConverter.)

ENDINT2:
CLR FIRST ; адрес уже был принят
RETI

;____________________________________________________________________

; Главная программа MAIN PROGRAM
ORG 0060h
MAIN:
; конфигурирование UART ADuC812
MOV SCON,#52h ; конфигурация UART для скорости 9600
MOV TMOD,#20h ; подразумевается частота кристалла 11.0592MHz
MOV TH1,#-3
SETB TR1

; конфигурирование и установка прерывания
MOV IE2,#01h ; установка прерывания I2C

SETB EX0 ; установка INT0
SETB IT0 ; INT0 edge triggered
SETB EA ; разрешает все прерывания
;начальные установки
MOV I2CADD,#044h ; адрес ведомого 44h
MOV I2CCON,#00h ; режим ведомого (по умолчанию=>не необходимое)
CLR GO ; сброс флага ожидания прерывания
; GO устанавливается однажды для данных TX'd или RX'd
SETB FIRST ; FIRST сбрасывается после приема
; первого принятого ведомым прерывания
MOV OUTPUT,#0 ; первый байт для передачи 40h
CLR LED
WAITFORDATA:
JNB GO,$ ; ----- ожидание прерывания i2c ------
; Если он в режиме приема, он
; ждет здесь второго прерывания (так как
; первое прерывание содержит только
; адрес ведомого в I2CDAT
; В режиме передачи
; производится выдача после первого прерывания.
SETB FIRST ; реинициализация флага
CLR GO
JB I2CTX,WAITFORDATA
; если ведомый только что передал данные, тогда
; ожидание приема байта данных
; если ведомый только что принял данные, тогда
; посылает принятый байт на UART
SENDUART:
CPL LED ; LED изменяется каждый раз как один байт
; принят и другой передан
MOV A,INPUT ; принятое значение посылается на UART
CALL SENDVAL
MOV A,#10
CALL SENDCHAR ; посылка LF + CR
MOV A,#13
CALL SENDCHAR
JNB RI, WAITFORDATA ; повторять (пока UART принимает данные)
; WHEN UART DATA RECEIVED, MOVE DATA TO I2C OUTPUT...
MOV OUTPUT, SBUF ; изменить OUTPUT на новое значение
CLR RI ; must clear RI
JMP WAITFORDATA ; возврат на главное ожидание
;============================================================
; SUBROUTINES
;============================================================
;____________________________________________________________________

; посылает ASCII значение содержащееся в A в UART
SENDCHAR:
JNB TI,$ ; ожидает отправки символа
CLR TI ; должен сбросить TI
MOV SBUF,A
RET
;____________________________________________________________________

; преобразует A в hex символ представляющий значение A's
; least значение полубайта
HEX2ASCII:
ANL A,#00Fh
CJNE A,#00Ah,$+3
JC IO0030
ADD A,#007h
IO0030: ADD A,#'0'
RET

;____________________________________________________________________

SENDVAL:
PUSH ACC
SWAP A
CALL HEX2ASCII
CALL SENDCHAR ; пересылает старший полубайт
POP ACC
PUSH ACC
CALL HEX2ASCII
CALL SENDCHAR ; пересылает младший полубайт
POP ACC
RET
;____________________________________________________________________

END

ГЛАВНАЯ СТРАНИЦА |  ТЕКУЩАЯ СТРАНИЦА;